この参照ガイドには、Vault で使用可能な演算子と関数の一覧が含まれます。数式を使用する Vault のすべての領域で、すべての関数と演算子が使用できるわけではありません。
数学演算子
+ (追加)
説明
2 つの値の合計を計算します
使用方法
値1 + 値2
データタイプ
- 数字
- 日時と数字 (数字を日数と解釈)
- 日付と数字 (数字を日数と解釈)
- 日付と時間
- 日付と間隔
- 日時と間隔
例
times_in_review__c + 1
- レビューの回数フィールドを 1 単位で増加します
created_date__v + 30
- 作成日に 30 日追加します
Date(Year(Today()), Month(Today()), Day(Today())) + Time(12,0,0)
- 本日の正午を表す日時を返します
Today() + Months(1)
- 翌月の同日を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
– (減算)
説明
2 つの値の差を計算します
使用方法
値1 - 値2
データタイプ
- 数字
- 日付
- 日時
- 日時と数字 (数字を日数と解釈)
- 日付と数字 (数字を日数と解釈)
- 日付と日時 (日時を日付に変換)
- 日付と間隔
- 日時と間隔
- 時間と時間 (差を分単位で返す)
例
suggested_retail_price__c - discount__c
- 割引後の価格を計算します
created_date__v - 1
- 作成日の前日を計算します
completion_date__c - created_date__v
- 日数、時間、分として 2 つの日時の差を計算します
Today() - Years(1)
- 前年の今日の日付を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
* (乗算)
説明
2 つの値を掛けます
使用方法
値1 * 値2
データタイプ
- 数字
例
monthly_cost__c * 12
- 年間コストを返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
/ (除算)
説明
1 つの値をもう 1 つの値で割ります
使用方法
値1 / 値2
データタイプ
- 数字
例
(measurement1__c + measurement2__c) / 2
- 2 つの測定値の平均を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
剰余
説明
もう 1 つの値で割った値の剰余
使用方法
値1 % 値2
データタイプ
- 数字
例
"Weeks:" & Text(Floor(days_required__c / 5)) &"Days:" & Text(days_required__c % 5)
- 必要な週数と日数のテキスト文字列を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
() (括弧)
説明
開き括弧と閉じ括弧内の式が先に評価されることを指定します
使用方法
(expression1) expression2
例
(measurement1__c + measurement2__c) / 2
- 2 つの測定値の平均を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
論理演算子
= (等しい)
説明
2 つの値が等しいかを評価します
使用方法
値1 = 値2
データタイプ
- 数字
- テキスト
- 日付
- 日時
- 日付と日時 (日時を日付に変換)
- はい/いいえ
- 選択リスト (両方の選択リストが単一の値であること)
- 選択リストとテキスト
例
Document.annotation_unresolved__v = 0
- 未解決の注釈がない場合に True を返します
created_date__v = last_modified_date__v
- オブジェクトレコードが作成されてから変更されていない場合に True を返します (日時は同値)
name__v = "text"
- 名前値が "text" に一致する場合に True を返します (テキスト文字列は同値)
picklist__c = "text__c"
- “text__c” に一致する項目が選択リストに含まれる場合に True を返します (選択リスト値がテキスト文字列に一致する)
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
! = (等しくない)
説明
2 つの値が等しくないかを評価します
使用方法
値1 ! = 値2
データタイプ
- 数字
- テキスト
- 日付
- 日時
- 日付と日時 (日時を日付に変換)
- はい/いいえ
- 選択リスト (両方の選択リストが単一の値であること)
- 選択リストとテキスト
例
amount1__c ! = amount2__c
- 数字が同値でない場合に True を返します
created_date__v ! = last_modified_date__v
- オブジェクトレコードが作成されてから変更されている場合に True を返します (日時は同値でない)
name__v ! = "text"
- 名前値が "text" に一致しない場合に True を返します (テキスト文字列は同値でない)
picklist__c != "text__c"
- “text__c” に一致する項目が選択リストに含まれない場合に True を返します (選択リスト値がテキスト文字列に一致しない)
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
< (次の値より小さい)
説明
最初の値が 2 つ目の値より小さいかどうかを評価します
使用方法
値1 < 値2
データタイプ
- 数字
- 日付
- 日時
- 日付と日時 (日時を日付に変換)
例
measurement1__c < measurement2__c
- 測定値 1 が測定値 2 より小さい場合、True を返します
If(due_date__c < Today(), "Late", "On-Time")
- 期日が現在の日付より前の場合に "Late" (遅延) を返します
(submission_date__c + 15) < approval_date__c
- 承認日が提出日の 15 日後移行に生じた場合に True を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
<= (次の値より小さいか等しい)
説明
1 つの値がもう 1 つの値以下かを評価します
使用方法
値1 <= 値2
データタイプ
- 数字
- 日付
- 日時
- 日付と日時 (日時を日付に変換)
例
measurement1__c <= measurement2__c
- 測定値 1 が測定値 2 以下の場合、True を返します
If(due_date__c <= Today(), "Due", "On-Time")
- 期日が現在の日付かそれ以前の場合に "Due" (期日) を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
> (次の値より大きい)
説明
最初の値が 2 つ目の値より大きいかどうかを評価します
使用方法
値1 > 値2
データタイプ
- 数字
- 日付
- 日時
- 日付と日時 (日時を日付に変換)
例
measurement1__c > measurement2__c
- 測定値 1 が測定値 2 以上の場合、True を返します
If(due_date__c > Today(), "On-Time", "Late")
- 期日が現在の日付より後の場合に "On-Time" (期限内) を返し、それ以外の場合には "Late" (遅延) を返します
approval_date__c > (submission_date__c + 15)
- 承認日が提出日の 15 日後移行に生じた場合に True を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
>= (次の値より大きいか等しい)
説明
1 つの値がもう 1 つの値以上かを評価します
使用方法
値1 >= 値2
データタイプ
- 数字
- 日付
- 日時
- 日付と日時 (日時を日付に変換)
例
measurement1__c >= measurement2__c
- 測定値 1 が測定値 2 以上の場合、True を返します
If(due_date__c >= Today(), "On-Time", "Due")
- 期日が現在の日付または後の場合に "On-Time" (期限内) を返し、それ以外の場合には "Due" (期日) を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
&& (および)
説明
2 つの値または式が両方 True かを評価します
使用方法
(expression1) && (expression2)
&& の代わりに And() を使用することができます。
例
(count__c >= expected_count__c) && (Today() < expiration_date__c)
- 件数が予想件数より大きいまたは等しく、かつ現在の日付が有効期限より前の場合に True を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
|| (または)
説明
2 つの値または式の 1 つ以上が True かを評価します
使用方法
(式1) || (式2)
次の代わりに Or() を使用することができます: | 。 |
例
(count__c >= expected_count__c) || (Today() < expiration_date__c)
- 件数が予想件数より大きいまたは等しい、または現在の日付が有効期限より前の場合に True を返し、両方の式が真の場合にも True を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
テキスト演算子
& (連結)
説明
2 つまたは複数のテキスト文字列を接続します
使用方法
text1 & text2
& の代わりに Concat() を使用することができます。
例
"Study" & name__v
- テキスト文字列 "Study" (治験) がオブジェクトレコードの名前と結合して返されます
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
日付および日時の関数
日付
説明
年、月および日の値が与えられている場合に日付値を返します
使用方法
日付(年, 月, 日)
例
Date(2018, 3, 14)
- 2018-03-14 の日付を返します
Date(year(today), month(today()) + 1, day(today()))
- 現在の日付から 1 ヶ月後の日付を返します
Date(Year(Today()), Month(Today()), Day(Today())) + Time(12,0,0)
- 本日の正午を表す日時を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
DateValue
説明
日時値の日付の部分を返します。この関数は、タイムゾーンの 2 番目のオプションパラメータとしても使用できます。返される日付は指定されたタイムゾーンに基づきます。
タイムゾーンパラメータは、選択リスト、テキストフィールド、またはタイムゾーンのテキストリテラル (「America/Los_Angele」や「Asia/Shanghai」など) になります。
使用方法
DateValue(DateTime)
または DateValue(DateTime, Timezone)
例
DateValue(audit_end_date_and_time__c)
- 時間を除く監査が終了した日付を返します
例
DateValue(audit_end_date_and_time__c, @User.timezone__sys)
- ユーザのタイムゾーンの時間を除く監査が終了した日付を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
日
説明
月の日付を返します
使用方法
日(日付)
例
Day(audit_end_date__c)
- 監査終了日の月の特定の日を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
日
説明
間隔として指定された日数を返します
使用方法
Days(数字)
例
audit_start_date__c + Days(10)
- 監査開始日から 10 日後の日付を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
時間
説明
DateTime の時間値を 0~23 で返します
時間は UTC 単位で返されます。ただし、DateTime を構築するために使用されている場合、Vault はその DateTime を有効なユーザの現地時間に変換します。
使用方法
Hour(dateTime)
または Hour()
例
(created_date__v)
- 作成日の時間を返します
Hour()
- Vault のタイムゾーンで現在の時間を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
Minute
説明
DateTime の分値を 0~59 で返します
分は UTC 単位で返されます。ただし、DateTime を構築するために使用されている場合は、その DateTime は有効なユーザの現地時間に変換されます。
使用方法
Minute(DateTime) または Minute()
例
Minute(created_date__v)
- 作成日の分を返します
Minute()
- Vault のタイムゾーンで現在の分を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
月
説明
日付または DateTime の月を 1~12 の数字で返します
使用方法
Month(date)、Month(DateTime)
例
Month(created_date__v)
- 作成日の月を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
月
説明
間隔として指定された月数を返します
使用方法
Months(数字)
例
audit_start_date__c + Months(1)
- 監査開始日から 1 ヶ月後の日付を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
NetWorkdays
説明
2 つの日付/日時の間にある就業日数を返します。この機能では、週末および祝日のスケジュールの任意のパラメータも許可されます。管理者は、企業管理者 > 祝日のスケジュールで祝日を設定するか、事前に設定された祝日を含む含むVPKを展開し、ダウンロードすることができます。
使用方法
NetWorkdays(start_date/datetime, end_date/datetime, weekend_number, holiday_schedule)
例
NetWorkdays(created_date__v, approval_date__c, 1, “United States”)
- 米国の祝日が削除された日付から次の日付までの就業日の日数を返します
使用可否
オブジェクト設定 | |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
今すぐ
説明
現在の日時を返します
有効なユーザの DateTime を返します。
使用方法
Now()
例
Now() - created_date__v
- 作成日からの日数を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
Second
説明
DateTime の秒値を 0~59 で返します
秒は UTC 単位で返されます。ただし、DateTime を構築するために使用されている場合は、その DateTime は有効なユーザの現地時間に変換されます。
使用方法
Second(日付)、Second()
例
Second(created_date__v)
- 作成日から秒値を返します
Second()
- Vault のタイムゾーンで現在の秒を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
StartOfDay
説明
与えられたのタイムゾーンの与えられたの日付の始まりの日時を返します。
タイムゾーンパラメータは、選択リスト、テキストフィールド、またはタイムゾーンのテキストリテラル (「America/Los_Angele」や「Asia/Shanghai」など) になります。
使用方法
StartOfDay(日付, タイムゾーン)
例
StartOfDay(assigned_date__v, "Europe/Oslo")
assigned_date__v
= 2020 年 7 月 1 日の場合、オスロ時間の 2019/07/01 00:00 に相当する UTC 日時を返します。
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
時間
説明
入力された時間、分、秒の値に基づいて時間を返します
使用方法
Time(時間, 分, 秒)
例
Time(12,0,0)
- 正午を表す時間を返します
Time(Hour(Now()), Minute(Now()), Second(Now())) - Time (12,30,0)
- 2 つの時間の差を分で計算します
Date(Year(Today()), Month(Today()), Day(Today())) + Time(12,0,0)
- 本日の正午を表す日時を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
今日
説明
Vault の基本タイムゾーンの現在の日付を返します。変数を使うと、特定のタイムゾーンの現在の日付を返すことができます
タイムゾーンパラメータは、選択リスト、テキストフィールド、またはタイムゾーンのテキストリテラル (「America/Los_Angele」や「Asia/Shanghai」など) になります。
使用方法
Today(), Today(タイムゾーン)
例
Today() = due_date__c
- 期日が Vault の基本タイムゾーンの現在の日付と等しい場合に True を返します
Today("Europe/Oslo") = due_date__c
- 期日がオスロのタイムゾーンで現在の日付と等しい場合に True を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
Today (ユーザ)
説明
有効なユーザの指定されたタイムゾーンで現在の日付を返します。
ライフサイクルまたはワークフローで使用されている場合、「ユーザ」はアクションを開始するユーザを参照します。例えば、ワークフロー所有者はワークフローの開始手順の直後に完了するアクションの「ユーザ」で、ワークフロータスク手順の直後に完了するアクションの「ユーザ」はタスクを完了する最後のユーザです。
使用方法
Today("user")
例
Today("user") = due_date__c
- 期日が有効なユーザのタイムゾーンで現在の日付と等しい場合に True を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
Weekday
説明
Date また DateTime の曜日を 1~7 の数字で返します
使用方法
Weekday(日付), Weekday(日時)
例
If((Weekday(due_date__v) = 1) || (Weekday(due_date__v) = 7)), "Weekend Due Date", "Not a weekend due date")
- 期日の曜日が日曜日または土曜日の場合は "Weekend Due Date" を戻し、それ以外の場合は "Not a weekend due date" を戻します。
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
Workday
説明
週末および (任意で) 祝日を差し引いた N 日後の日付を返します。この機能では、週末および祝日のスケジュールの任意のパラメータも許可されます。管理者は、企業管理者 > 祝日のスケジュールで祝日を設定するか、事前に設定された祝日を含む含むVPKを展開し、ダウンロードすることができます。
使用方法
Workday(start_date/datetime, number_of_days, weekend_number, holiday_schedule)
例
Workday(created_date__v, N)
- 土曜日と日曜日を除いて、作成部から N 日前の日付を返します
Workday(created_date__v, N, 1, “United States”)
- 米国の祝日を除いて、作成部から N 日前の日付を返します
使用可否
オブジェクト設定 | |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
年
説明
日付から年を返します
使用方法
Year(日付)
または Year(DateTime)
例
Date(Year(Today()) + 1, Month(Today()), Day(Today()))
- 翌年の現在の日付と同じ日を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
年
説明
間隔として指定された年数を返します
使用方法
Years(数)
例
Today() + Years(1)
- 翌年の現在の日付と同じ日を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
廃止された関数
以下の関数は廃止されました。
注: 廃止された関数は入力することで引き続きご利用になれますが、数式作成 UI には表示されません。
演算機能
Abs
説明
数字の絶対値を計算します
使用方法
Abs(数字)
例
Abs(height_1__c - height_2__c)
- Height 1 と Height 2 の差を、どちらの測定値が大きいかに関わらず正の値を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
平均
説明
一連の数字の平均を計算する
使用方法
Average(number1, number2, ...)
例
Average(1.5, 2, 3, 4, 5.0)
- 3.1 を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
Ceiling
説明
値の次に大きい整数を返します
使用方法
Ceiling(数字)
例
Ceiling(14.2)
- 最も近い整数に四捨五入して 15 を返します
Ceiling(-14.2)
- 最も近い整数に四捨五入して -14 を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
Floor
説明
値の次に小さい整数を返します
使用方法
Floor(数字)
例
Floor(14.2)
- 小数点以下を切り捨てて最も近い整数までの概算にして 14 を返します
Floor(-14.2)
- 小数点以下を切り捨てて最も近い整数までの概算にして -15 を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
最高
説明
集合から最大の値を返します
使用方法
Max(value1, value2, …)
データタイプ
- 数字
- 日付
- 日時
単一の Max()
リクエストにデータタイプを組み合わせることはできません。日付と日時を組み合わせる必要がある場合は、DateValue を使用して日時を日付に変換することをお薦めします。
例
Max(measurement1__c, measurement2__c, measurement3__c)
- 最大の測定数を返します
Max((units__c * price__c), min_value__c)
- 価格で乗じた単位または最小値の大きい方を返します
Max(approval_date__c, today(), completed_date__v
- 任意の日付の大きい方で、最新の (近い) 日付を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
最低
説明
集合から最小の値を返します
使用方法
Min(値1, 値2, …)
データタイプ
- 数字
- 日付
- 日時
単一の Min()
リクエストにデータタイプを組み合わせることはできません。日付と日時を組み合わせる必要がある場合は、DateValue を使用して日時を日付に変換することをお薦めします。
例
Min((units__c * price__c), max_value__c)
- 価格で乗じた単位または最大値の小さい方を返します
Min(approval_date__c, today(), completed_date__v
- 任意の日付の小さい方で、最も過去の (古い) 日付を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
べき乗
説明
数字が 2 つある場合、最初の数字を 2 番目の数字と同じ回数掛け合わせます
使用方法
Power(数字, 数字)
例
Power(5, 3)
- 5 を 3 回掛けて (5 × 5 × 5) 125 を返します
Power(8, 1/3)
- 8 を 1/3 回掛けて (8 × ⅓) 2 を返します
Power(9, 0)
- 1 を返す: 2 番目の数字がゼロの場合、結果は常に 1 になります。
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
四捨五入
説明
数字を定義された小数位で四捨五入します
使用方法
Round(数字, 数字)
例
Round(5.5, 0)
- 5.5 の小数第一位を四捨五入して "6" を返します
Round(5.54, 1)
- 5.54 の小数第二位で四捨五入して "5.5" を返します
Round(-5.5, 0)
- -5.5 の小数第一位を四捨五入して "-6" を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
四捨五入(重要)
説明
定義された有効桁数に丸められます
使用方法
Round(number, number_of_digits, "significant")
OR Round(number, number_of_digits, "significant-astm")
例
Round(0.445, 2, "significant")
- 「0.45」を返します
Round(0.445, 2, “significant-astm”)
- 「0.44」を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
Sqrt
説明
数字の平方根を返します
使用方法
Sqrt(数字)
例
Sqrt(25)
- 25 の平方根の "5" を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
合計
説明
指定された数字を合計します
使用方法
Sum(数字1, 数字2, ...)
例
Sum(1.5, 2, 3, 4, 5.0)
- 15.5 を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
値
説明
テキスト文字列を数字として返します; テキストが数字に変換されない場合関数はエラーになります
使用方法
Value(テキスト)
例
Value(Right("S1234",4)
- 数字 "1234" を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
廃止された関数
NumberEquals
: = 演算子を使用します。
注: 廃止された関数は入力することで引き続きご利用になれますが、数式作成 UI には表示されません。
論理関数
および
説明
すべての式が True の場合に True を返します
And() の代わりに && を使用することができます。
使用方法
And(expression1, expression2, …)
例
And(due_date__v = today(), status__v ! = "完了")
- オブジェクトレコードの期日が今日で、かつそのステータスが "Completed" (完了) でない場合に True を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
症例
説明
式の値を各ケース値と比較して対の結果を返します。一致する値がない場合、最後の引数を返します
式の引数には次のデータタイプが使用できます: 数字、テキスト、はい/いいえ、選択リスト。選択リストで作業する際に、フィールドは値ラベル (Study123) ではなく値名 (study123_c) を返します。
使用方法
Case(expression1, value1, result1, value2, result2, else_result)
例
Case(WeekDay(Today()), 1, "Sunday", 2, "Monday", 3, "Tuesday", 4, "Wednesday", 5, "Thursday", 6, "Friday", 7, "Saturday", "None")
- 現在の曜日を返します
Case(picklist__c, "sunday__c", 1, "monday__c", 2, "tuesday__c", 3, "wednesday__c", 4, "thursday__c", 5, "friday__c", 6, "saturday__c", 7, 0)
- ラベル (日曜日) ではなく、選択リスト値名 (sunday__c) を使用して選択リストで選択された曜日の数字を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
もし
説明
式が True または False かどうかを判断します。True の場合は任意の値を、False の場合は別の値を返します。
使用方法
If(式, value_if_true, value_if_false)
例
If(Or(IsBlank(measurement1__v), IsBlank(completed_date__v)), "Incomplete", "Complete")
- 測定値 1 と完了日の両方が空白でない場合に "Complete" (完了) を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
Includes
説明
複数値選択リストに、定義された文字列または単一の値の選択リストに一致する名前が含まれる場合に True を返します
使用方法
Includes(multi-value picklist, string)
または Includes(multi-value picklist, single-value picklist)
例
Includes(colors__c, 'red__c')
- “Red” が複数値選択リスト “colors__c” で選択された値の 1 つである場合に True を返します
Includes(colors__c, Picklist.field__v.value__v)
: 単一の値の選択リストで定義された値が、複数値選択リスト “colors__c” で現在選択されている場合に True を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
IsBlank
説明
値が空白の場合に True を返します
使用方法
IsBlank(式)
例
If(Or(IsBlank(measurement1__v), IsBlank(completed_date__v)), "Incomplete", "Complete")
- 測定値 1 と完了日の両方が空白でない場合に "Complete" (完了) を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
IsNumber
説明
値が数字の場合に True を返します
使用方法
IsNumber(テキスト)
例
If(IsNumber(measurement1__c),measurement1__c/100,0)
- 測定値 1 が数字の場合に 100 で割った測定値 1 を返します。それ以外の場合は "0" を返します。
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
条件反転
説明
式が False の場合に True を、式が True の場合に False を返します
使用方法
Not(式)
例
Not(isBlank(due_date__c))
- 期日フィールドに入力されている場合に True を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
または
説明
2 つの値または式の 1 つ以上が True かを評価します
使用方法
(式1) || (式2)
Or() の代わりに | を使用することができます。 |
例
Or((count__c >= expected_count__c),(Today() < expiration_date__c))
- 件数が予想件数より大きいまたは等しい、または現在の日付が有効期限より前の場合に True を返し、両方の式が真の場合にも True を返します
Or(due_date__v = Today(), due_date__v = Today() + 1)
- オブジェクトレコードの期日が今日または明日の場合に True を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
テキスト関数
Concat
説明
2 つまたは複数のテキスト文字列を接続します
使用方法
Concat(テキスト1, テキスト2, …)
Concat() の代わりに & を使用することができます。
例
Concat("Study", name__v)
- テキスト文字列 "Study" (治験) がオブジェクトレコードの名前と結合して (例: "Study123") 返されます
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
検索
説明
テキストの文字列内の文字列の位置を返します
使用方法
Find(subtext, text)
例
Find(" ", "4280 Hacienda Dr, Pleasanton, CA")
- 住所の最初のスペースの位置である 5 を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
ID
説明
レコードIDをオブジェクト参照値のテキストで返します
使用方法
ID(text/object_record)
例
ID(country__c)
Country__c
フィールドで参照されているオブジェクトレコードのIDを返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
アイコン
説明
式評価に基づいてアイコンを表示します
使用方法
icon(name, color, text)
テキスト式は任意で、ユーザの代替テキストを提供します。詳しくは、Vault がサポートするアイコンを参照してください。
例
If(completeness_v = 'complete_v', Icon("circle", "#00C345", "Complete"), Icon("circle", "#ff0000", "Incomplete"))
: 完了度選択リスト値に基づいて状況アイコンを表示します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
左
説明
テキスト文字列の始まりから指定された文字数を返します
使用方法
Left(テキスト, 位置)
例
Left(name__v, 5) & " - " & abbreviation__c
- 名前の最初の 5 文字ととその略語が結合されたもの (例: “Chole – CC”) を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
長さ
説明
指定されたテキスト文字列の文字数を返します
使用方法
Length(テキスト)
例
Length(name__v)
- 名前フィールドの文字数を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
Lower
説明
指定されたテキスト文字列のすべての文字を小文字に変換します
使用方法
Lower(テキスト)
例
Lower("Company A")
- 文字列 “company a” を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
ミドルネーム
説明
2 つの指定された位置間のテキスト文字数を返します
使用方法
Middle(テキスト, start_position, end_position)
例
Middle("4280 Hacienda Dr, Pleasanton, CA", 6, 13)
- "Hacienda" のテキスト文字列を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
右
説明
テキスト文字列の終わりから指定された文字数を返します
使用方法
Right(テキスト, 数字)
例
Value(Right("S1234",4))
- 数字 "1234" を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
Substitute
説明
テキスト文字列の古いテキストを新しいテキストに置き換えます
使用方法
Substitute(テキスト, old_text, new_text)
例
Substitute("Total cost of ownership: $1,000", "$", "£")
- ドル記号がポンド記号に置き換えられた同じテキスト文字列を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
テキスト
説明
指定された形式に基づいて値をテキストに変換します
使用方法
Text(日付/日時/数字,フォーマット)
または Text(lifecycle_state/picklist_value/object_record)
番号をテキストに変換する際、「形式」
式は任意です。指定したフォーマットは二重引用符 (") で囲む必要があります。指定された形式がない Text()
関数を渡す場合、Vault は定義されている現在の小数位を保存します。小数位が異なるオペランドの場合、Vault は小数位が最も多い値を保存します。例えば、Text(3.14+2.345)
は 5.485
を返します。
注: 2 つの選択リストを比較する際に Text(picklist_value)
の使用は推奨されません。これを実行すると、選択リストのオプションそのものではなく、ローカライズ済みの選択リストのオプションラベルが比較されます。代わりに選択リストのオプション名、例えば「red__c」などの使用が推奨されます。「red__c」はパブリックラベルです。
例
"Today is" & Text(Today(), "dddd")
- "Today is" の次に曜日の完全な名前が続いたもの (例: "Today is Monday") のテキスト文字列を返します
Text(state__v)
- ライフサイクル状態ラベルの文字列 "Planned" を返します
Text(Document.major_version_number__v, "###") & "."& Text(Document.minor_version_number__v, "###")
- テキスト文字列 “#.#" を返します。# はドキュメントのメジャーバージョン番号およびマイナーバージョン番号 ("12.2" など) です
Text(region__c)
region__c
フィールドで参照されているオブジェクトレコードの名前を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
Trim
説明
テキスト文字列の始まりと終わりのスペースとタブを削除します
使用方法
Trim(テキスト)
例
Trim(" Phase III ")
- 文字列の前からスペースを削除したテキスト文字列 "Phase III" を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
Upper
説明
指定されたテキスト文字列のすべての文字を大文字に変換します
使用方法
Upper(テキスト)
例
Upper("Company A")
- 文字列 “COMPANY A” を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
その他の関数
ハイパーリンク
説明
クリック可能なリンクとしてテキストを表示します
使用方法
Hyperlink(href, label, target, connection)
この関数はリンク戻り型を使用する数式フィールドで使用する必要があります。
引数
- href: リンクのクリック可能な URL; テキスト文字列、その他の関数、フィールド参照、および文字列を返す式を使用することができます。リテラルテキスト文字列を使用する場合は、一重引用符 (”) で囲む必要があります。
- ラベル:UI のリンクとして表示されるテキスト; この引数内でテキスト文字列、その他の関数、フィールド参照、および文字列を返す式を使用することができます。リテラルテキスト文字列を使用する場合は、一重引用符 (”) で囲む必要があります。
- ターゲット: リンクを現在のタブで開くか、新しいブラウザタブ/ウィンドウで開くかを決定します; ‘new_window’ および ‘same_window’ が使用できます。属性は一重引用符 (”) で囲む必要があります。
- 接続: (任意) 設定されている接続オブジェクトレコードを使用して URL 内の別の Vault の DNS に入力します。形式は@Connection{接続 API 名}、例えば @Connection.veepharm_v2v のようになります。詳細は、接続の作成および管理をご覧ください。
例
Hyperlink('https://veepharm.com', 'VeePharm Site', 'new_window')
- この例では、特定の URL に簡単に進むことができます。フィールドには「VeePharm Site」と表示され、指定された URL に進みます。ここでは同じタブまたはウィンドウに表示するのではなく、新しいタブまたはウィンドウが開きます。
Hyperlink(Concat("https://veepharm.theorgwiki.com/employees/", first_name__sys, "_", last_name__sys), Concat(first_name__sys, " ", last_name__sys), 'new_window')
- この例では、ユーザオブジェクトレコードと一緒に使用して、ユーザの OrgWiki の企業プロフィールに戻ります。数式にはユーザの姓名が入ったラベルと一緒にクリック可能なリンクが表示され、ユーザの OrgWiki プロフィールページに進みます。
Hyperlink(Concat("/ui/#t/0TB00000000N04/", related_record_id__c), related_record_label__c, 'same_window', @Connection.veepharm_v2v)
- この例では、API 名「veepharm_v2v」の Vault 間接続レコードを使用します。href 引数と接続引数を一緒に使用することにより、ユーザは接続されている Vault の特定のレコードに進みます。この例は接続レコードを使用しているため、href 引数の DNS の後に URL 部分のみが含まれます。
使用可否
この関数は、戻り型がリンクのオブジェクトの数式タイプフィールドでのみ使用可能です。
オブジェクト設定 | |
オブジェクトライフサイクルアクション | |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
RecordByLabel
説明
指定されたオブジェクトラベルのオブジェクト参照 (複数ある場合は最も古いもの) を返します。
使用方法
RecordByLabel()
例
RecordByLabel (“Cholecap”)
- Cholecap 製品のオブジェクト参照を返します
使用可否
オブジェクト設定 | |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
州
説明
オブジェクトまたはドキュメントライフサイクル状態の名前を返します
使用方法
state__v
例
state__v = "planned_state__v"
- ライフサイクル状態名の値が
planned_state__v
の場合、True を返します
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション | ✓ |
各カテゴリーに含まれるものをご確認ください。
URL エンコード
説明
スペースを %20 に変換するなど、文字列の文字を URL から送信できる形式に変換します
使用方法
Urlencode(テキスト)
例
Hyperlink(Concat("https://www.google.com/search?q=", Urlencode(claim_text__c)), 'Search', 'new_window')
- この例は、クレームテキストフィールドの文字列を Google 検索します。このフィールドにはスペースとその他の URL 以外のエンコード化された文字がある場合があり、式は Urlencode() を使って文字列を適切にエンコード化します。
使用可否
オブジェクト設定 | ✓ |
オブジェクトライフサイクルアクション | ✓ |
ドキュメントライフサイクルアクション |
各カテゴリーに含まれるものをご確認ください。
日付形式
フォーマット | 例 | 説明 |
d | 1 | 1 桁の月の日付 |
dd | 01 | 2 桁の月の日付 |
ddd | Thu | 3 桁の曜日名 |
dddd | 木曜日 | 完全な曜日名 |
mm | 03 | 2 桁の月 |
mmm | 3 月 | 3 文字の月名 |
mmmm | 3 月 | 完全な月名 |
yy | 17 | 2 桁の年 |
yyyy | 2017 | 完全な年 |
dd-mm-yyyy | 31-03-2017 | ハイフンで区切られた日付、月、年 |
yyyymmdd | 20170331 | 区切られていない日付、月、年 |
dd.mmm.yyyy | 31.Mar.2017 | ピリオドで区切られた日付、3 文字の月名、年 |
yyyy-mm-dd | 2017-03-31 | ハイフンで区切られた年、月、日付 |
Mmmm yyyy | March 2017 | 完全な月名と完全な年 |
dddd dd/mm/yy | Thursday 31/03/17 | 完全な曜日名と、スラッシュで区切られた日付、月、2 桁の年 |
番号形式
フォーマット | 例 | 説明 |
0 | 1 | 小数のない数字 |
# | 1 | 小数のない数字 (数字がない場合はゼロ) |
0.00 | 1.20 | 小数第二位で切り上げ |
#.## | 1.2 | 小数第二位で切り上げ (数字がない場合はゼロ) |
$# | $10 | 通貨フォーム (異なる通貨を使用できます) |
#,### | 10,000 | 左から 3 桁目をコンマで区切る (複数のコンマを使用できます) |
#,###.## | 10,000.12 | 左から 3 桁目をコンマで区切り、小数第二位で切り上げ |
-# | -10 | 数字の前のマイナスアイコン |
% | %1000 | 100 倍してパーセントで表示 (パーセントが先) |
#% | 1000% | 100 倍してパーセントで表示 (数字が先) |
#,###E0 | 1.234E3 | 科学的記数法の仮数と指数を分離します |
関数および演算子の使用可否
Vault 内のさまざまな管理領域で異なる機能と演算子の使用が許可されています。上の使用可否のセクションで、使用できる関数または演算子をご確認いただけます。
- オブジェクト設定には、オブジェクトの初期化フィールド、オブジェクトの形式タイプフィールド、オブジェクトページレイアウトルール、ワークフロー開始手順ルール、レコードバリデーションルールが含まれます。
- オブジェクトライフサイクルアクションには、レコードフィールドの更新 ワークフローアクションとレコードフィールドの更新ライフサイクル状態のエントリアクションが含まれます。
- ドキュメントライフサイクルアクションには、フィールドを数式で設定するライフサイクル状態のエントリアクションと、ドキュメントフィールドの更新ワークフローアクションが含まれます。
システム変数
システム変数は、Vault が参照できる値を格納する動的オブジェクトです。使用するコンテキストに応じて値が変化するという点から、システム変数は動的になります。例えば、@User
は、有効なユーザのプロファイルを指し、電子メールアドレスのようなフィールド値へのアクセスを許可します。
注: ライフサイクルとワークフローの設定は、このコンテキストのアクションでシステムユーザが使用されるため、@User
のシステム変数を効率的に使用できません。
選択リストの値の表現
表現を使って数式の選択リスト値を参照できます。
使用方法
選択リスト。<選択リスト名>。<選択リスト値名>
例
Picklist.impact__c.high__c
- 「インパクト」選択リストの「高い」値を返します。
if(object_type__v = "Action Plan", Picklist.ap_securityc.analysis_and_action_planc, Picklist.ap_securityc.action_plan__c)
- オブジェクトタイプが「アクションプラン」の場合、「アクションプランセキュリティ」選択リストから「分析およびアクションプラン」を返します。もしくは、「アクションプランセキュリティ」選択リストから「アクションプラン」値を返します。
コメントおよびフォーマット
コメントおよびフォーマットを使うと、ユーザおよび他の管理者は数式表現がどのように機能するかを理解することができます。
ユーザは、次のルールに基づき、数式表現フィールド内にコメントを追加できます。
- コメントはフィールド内で最初のテキストである必要があります
- コメントはこの形式に従う必要があります: /* {COMMENT} */
Vault は数式表現内で特定のフォーマットを保持します:
- 改行
- スペース
Null 値
数式表現を使用して、フィールド値を空白に設定する NULL 値を返すことができます。
数式表現の評価時に、NULL 値のために Vault でエラーが生じると、Vault は必ず NULL
値を返します。例えば、NULL + 1
は NULL
を返します。